iCal and Mailsmith

Has anyone tried the new iCal (1.0.1) with Mailsmith? It seems like it breaks the work-around posted here a couple of months ago for modifying the scripts to use Mailsmith to send notification.

Correct.

The formerly used scripts still exist, bot do not seem to be used anymore. Instead, iCal uses a single script Mail.applescript and its compiled form Mail.scpt, which are located in iCal/Contents/Resources/ as well.

I ported the old changes to this script, which now looks like this (mind line breaks!)

Save the file as script and compiled script (using AppleScript Editor 2.0).

The changes seem to work quite well. I have tried some eMail notifications. Please remember to put the script in iCal/Contents/Resources/iCal Helper/Contents/Resources/ as well, since the script located there will be used for notification if iCal is not currently running.

The Strings for notification Mails are now located in iCal/Contents/Resources/English.lproj/iTIP.strings (ow whichever lproj you use). To correct the line endings, all "\n" on the right hand side of the equals sign have to be replaced by "\r".

Regards, Peter.


-- Mail.applescript
-- iCal

on send_mail_sb(subjectLine, messageText)
    tell application "Mailsmith 1.5"
        set mymail to make new message window
        tell mymail
            set subject to subjectLine
            set the contents to messageText
        end tell
        set visible of mymail to true
        activate
    end tell
end send_mail_sb

on send_mail_sbr(subjectLine, messageText, myrecipient)
    tell application "Mailsmith 1.5"
        set mymail to make new message window
        tell mymail
            set subject to subjectLine
            set the contents to messageText
            make new to_recipient at end with properties {address string:myrecipient}
        end tell
        send mymail
    end tell
end send_mail_sbr

on send_mail_sbrp(subjectLine, messageText, myrecipient, invitationPath)
    set pfile to POSIX file invitationPath
    set myfile to pfile as alias
    tell application "Mailsmith 1.5"
        set mymail to make new message window
        tell mymail
            set subject to subjectLine
            set the contents to messageText
            make new to_recipient at end with properties {address string:myrecipient}
            make new enclosure at end with properties {file:myfile}
        end tell
        set visible of mymail to true
        send mymail
    end tell
end send_mail_sbrp