Increase/decrease font size

These are two scripts to increase and decrease the font size of the front window. Depending on the layout and length of some messages, I prefer to view them using a larger font. These scripts will cycle (up or down) through a preset list of font sizes. Script will beep if the largest (or smallest) size from the list has already been set.

I have set the keystroke shortcut to Cmd-shift-minus and Cmd-shift-plus; you may want to do the same.

I am not sure if the script works with all window types. I have tested it with Mail Browser, Mailbox, and Message windows.

I have set the list to font sizes {7, 9, 12, 14, 18}. You should change the fontSizes property to the list of sizes that work well with your default font.

I also included a simple (one line) script for setting a specific font size.


--Set Font larger;  set key to cmd-shift-plus

property fontSizes : {7, 9, 12, 14, 18}
tell application "Mailsmith"
    set fontSize to display font size of window 1
    set fontCnt to length of fontSizes
    set fontChanged to false
    repeat with i from 1 to fontCnt
        if fontSize = item i of fontSizes then
            if i = fontCnt then
                beep
            else
                set display font size of window 1 to item (i + 1) of fontSizes
            end if
            set fontChanged to true
            exit repeat
        end if
    end repeat
    if not fontChanged then set display font size of window 1 to ¬
        item 1 of fontSizes
end tell

--------------------------------------

--Set Font smaller;  set key to cmd-shift-minus

property fontSizes : {7, 9, 12, 14, 18}
tell application "Mailsmith"
    set fontSize to display font size of window 1
    set fontCnt to length of fontSizes
    set fontChanged to false
    repeat with i from fontCnt to 1 by -1
        if fontSize = item i of fontSizes then
            if i = 1 then
                beep
            else
                set display font size of window 1 to item (i - 1) of fontSizes
            end if
            set fontChanged to true
            exit repeat
        end if
    end repeat
    if not fontChanged then set display font size of window 1 to ¬
        item fontCnt of fontSizes
end tell

--------------------------------------

--Set Font 9pt
tell application "Mailsmith" to ¬
    set display font size of window 1 to 9